Problem with listViews

(I already posted my problem to an existing thread, but maybe I had better opened a new thread ..)

I have two listViews in one dialog box.
The first has two columns, the second one four.
The second listView is filled when an item in the first listView is selected,
and it shows the correct values in all four columns as expected.
Only I cannot get the first listView to show any value in the second column.
Any ideas?

Karl
kabr - Wed Oct 13 07:31:44 EDT 2010

Re: Problem with listViews
Doug.Zawacki - Wed Oct 13 10:34:36 EDT 2010

Kabr,
Please post your code so we can see what's going on. Based on your description you understand how to populate multiple columns so I don't understand where the problem is until I see the code.

Re: Problem with listViews
kabr - Wed Oct 13 11:30:27 EDT 2010

Doug.Zawacki - Wed Oct 13 10:34:36 EDT 2010
Kabr,
Please post your code so we can see what's going on. Based on your description you understand how to populate multiple columns so I don't understand where the problem is until I see the code.

Hi Doug,

thanks for your response.
Here's the code:
this loop fills the first listView, but the second column remains empty no matter what

for bsd in current Folder do {
    bsdName = name(bsd) 
        bsdDesc = description(bsd)
        insert(dbeBLSetDefListView, j, "", iconBLSD)
        set(dbeBLSetDefListView, j, 0, bsdName)
        set(dbeBLSetDefListView, j, 1, bsdDesc)
        j++
}

and this loop fills the second listView with all four columns filled correctly

for bs in bsd do {
    strVersion = versionID(bs) ""
        strDateof = stringOf(dateOf(bs))
        blsUser = user(bs)
        
        if (!isOpen(bs)) {
                insert(dbeBLSetListView, i, "",iconBLS)
                set(dbeBLSetListView, i, 3, "closed")
        } else {
                insert(dbeBLSetListView, i, "",iconOpenBLS)
                set(dbeBLSetListView, i, 3, "open")
        }
        set(dbeBLSetListView, i, 0, strVersion)
        set(dbeBLSetListView, i, 1, strDateof)
        set(dbeBLSetListView, i, 2, blsUser)
        i++
}

the loops are in two different functions.

best regards
Karl

Re: Problem with listViews
Doug.Zawacki - Wed Oct 13 12:17:47 EDT 2010

kabr - Wed Oct 13 11:30:27 EDT 2010

Hi Doug,

thanks for your response.
Here's the code:
this loop fills the first listView, but the second column remains empty no matter what

for bsd in current Folder do {
    bsdName = name(bsd) 
        bsdDesc = description(bsd)
        insert(dbeBLSetDefListView, j, "", iconBLSD)
        set(dbeBLSetDefListView, j, 0, bsdName)
        set(dbeBLSetDefListView, j, 1, bsdDesc)
        j++
}

and this loop fills the second listView with all four columns filled correctly

for bs in bsd do {
    strVersion = versionID(bs) ""
        strDateof = stringOf(dateOf(bs))
        blsUser = user(bs)
        
        if (!isOpen(bs)) {
                insert(dbeBLSetListView, i, "",iconBLS)
                set(dbeBLSetListView, i, 3, "closed")
        } else {
                insert(dbeBLSetListView, i, "",iconOpenBLS)
                set(dbeBLSetListView, i, 3, "open")
        }
        set(dbeBLSetListView, i, 0, strVersion)
        set(dbeBLSetListView, i, 1, strDateof)
        set(dbeBLSetListView, i, 2, blsUser)
        i++
}

the loops are in two different functions.

best regards
Karl

ok...but now the question is how you build the ListView DBE...did you in fact call insertColumn() for both columns? You must have those columns created. still not enough code.

Re: Problem with listViews
kabr - Thu Oct 14 05:44:49 EDT 2010

Doug.Zawacki - Wed Oct 13 12:17:47 EDT 2010
ok...but now the question is how you build the ListView DBE...did you in fact call insertColumn() for both columns? You must have those columns created. still not enough code.

alright, here's the complete code:

// BaselineSets.dxl
 
 
pragma runLim, 0
 
string dummyList[]      = {}
 
Folder currFolder = current Folder 
 
DB  dbBaselineSetAll       = null
DBE dbeCurrentFolderField  = null
DBE dbeLabelFrame          = null
DBE dbeDescriptionLabel    = null
DBE dbeListsFrame          = null
DBE dbeBLSDLabel           = null
DBE dbeBLSetDefListView    = null
DBE dbeBLSLabel            = null
DBE dbeBLSetListView       = null
DBE dbeFileLabel           = null
DBE dbeExportFile          = null
DBE dbeRun                 = null
 
BaselineSetDefinition bsdglobal = null
 
string strbsd     = ""
string strVersion = ""
 
bool statusBLS = false
 
/******************************************************************************
    contextOK
******************************************************************************/
bool contextOk() {
        currFolder = current Folder
        
        if (null currFolder) {
                infoBox("Please run this script from within a folder")
                return false
        }
        return true
}
 
bool fileExists_(string strfilename) {
    Stat s 
    s = create strfilename 
    if (null s) return false 
    delete s 
    return true 
}
 
/******************************************************************************
        fillBaselineSetDefinitions
******************************************************************************/
 
void fillBaselineSetDefList() {
        empty(dbeBLSetDefListView)
        j       = 0
        string bsdName = ""
        string bsdDesc = ""
        BaselineSetDefinition bsd
 
        for bsd in current Folder do {
                bsdName = name(bsd) 
                bsdDesc = description(bsd)
 
                insert(dbeBLSetDefListView, j, "", iconNone)
                set(dbeBLSetDefListView, j, 0, bsdName)
                set(dbeBLSetDefListView, j, 1, bsdDesc)
                j++
        }
        if (null bsdName) {
                insert(dbeBLSetDefListView, 0, "", iconNone)
                set(dbeBLSetDefListView, 0, 0, "(No Baseline Set Definitions)")
                set(dbeBLSetDefListView, 0, 1, "in current folder")
        }
}
 
void doRunScript(DB btn) {
        string bsdName = ""
        string strTemp = ""
        string strCompare = ""
        string strDate = ""
        string strbs = ""
        BaselineSet bs
        ModuleVersion mv
        Baseline bl
        Baseline blcompare
        string strDatebl = ""
        string strfilename = ""
        Module currmod
        ModName_ currmodname
 
        strfilename = get(dbeExportFile)
        Stream out = write strfilename 
        out << "List of Modules contained in specific Baseline Set" "\n\n"
 
        for strTemp in dbeBLSetListView do {
                strbs = strTemp
        }
        
        if (null bsdglobal) {
                ack "Please select a baseline set before you continue!"
                halt
        }
        
        for bs in bsdglobal do {
                strMajor = major(bs) ""
                strMinor = minor(bs) ""
                strVersion = versionID(bs) ""
                strDateof = stringOf(dateOf(bs))
                bsdName = strVersion ", created " strDateof
                if (strVersion == strbs) {
                        break
                }
        }
 
        out << "Baseline Set Definition Information:\n"
        out << "Name       : " name(bsdglobal) "\n"
        out << "Description: " description(bsdglobal) "\n\n"
 
        out << "Baseline Set Information:\n"
        out << "Version    : " strVersion "\n"
        if (isOpen(bs) == true) {
                out << "Status     : Open\n"
        } else {
                out << "Status     : Closed\n"
        }
        out << "Annotation : " annotation(bs) "\n"
        out << "created by : " user(bs) "\n"
        out << "created on : " dateOf(bs) "\n"
        out << "\n"
        out << "Modules:\n"
 
        for mv in all bs do {
                bl = baseline mv
                if (null bl) {
                        strCompare = ""
                        strDate = ""
                } else {
                        currmod = read((fullName mv),false,true)
                        if (!null currmod) {
                                strCompare = (major bl) "." (minor bl) " " (suffix bl) ""
                                for blcompare in currmod do {
                                        tmpString = (major blcompare) "." (minor blcompare) " " (suffix blcompare) ""
                                        if (tmpString == strCompare) {
                                                strDate = ", created on " (dateOf blcompare) ""
                                        }
                                }
                                close(currmod)
                        }
                }
                out << (fullName mv) " "
                string vString = (versionString mv)
                if (vString != "") {
                        out << "[" (versionString mv) "]" 
                } else {
                        out << "[-]"
                }
                out << strDate "\n"
        }
        close(out)
        string buttons[] = {"OK"} 
        int answer = messageBox("BLSD report done",buttons, msgInfo)
}
 
/******************************************************************************
        doSelect
******************************************************************************/
void doSelect(DBE bsdList, int j) {
        string strTemp = get(dbeBLSetDefListView)
        if (strTemp == "(No Baseline Set Definitions)") {
                halt
        }
        int i = 0
        string strbsd = ""
        strTemp = ""
        string strMajor = ""
        string strMinor = ""
        string strVersion = ""
        string strDateof = ""
        string bsdName = ""
        string bsdDesc = ""
        string blsUser = ""
        BaselineSet bs
 
        for strTemp in bsdList do {
                if (strTemp == "No Baseline Set Definitions") halt
                strbsd = strTemp
        }
        empty(dbeBLSetListView)
        for bsdglobal in current Folder do {
                bsdName = name(bsdglobal)
                bsdDesc = description(bsdglobal)
                if (bsdName == strbsd) {
                        break
                }
        }
        for bs in bsdglobal do {
                strMajor = major(bs) ""
                strMinor = minor(bs) ""
                strVersion = versionID(bs) ""
                strDateof = stringOf(dateOf(bs))
                blsUser = user(bs)
                bsdName = strVersion ", created " strDateof
 
                if (!isOpen(bs)) {
                        insert(dbeBLSetListView, i, "",iconNone)
                        set(dbeBLSetListView, i, 3, "closed")
                } else {
                        insert(dbeBLSetListView, i, "",iconNone)
                        set(dbeBLSetListView, i, 3, "open")
                }
                set(dbeBLSetListView, i, 0, strVersion)
                set(dbeBLSetListView, i, 1, strDateof)
                set(dbeBLSetListView, i, 2, blsUser)
                i++
        }
}
 
void undoSelect(DBE dbe, int i) {
        empty(dbeBLSetListView)
        inactive(dbeExportFile)
        inactive(dbeRun)
        set(dbeExportFile, "C:\\Temp\\")
}
 
void setFileName(DBE dbe, int i) {
        strbsd = get(dbeBLSetListView, i)
        bsdName = get(dbeBLSetDefListView)
        string exportFileName = "C:\\Temp\\BLS_" bsdName "_" strbsd ".txt"
        set(dbeExportFile, exportFileName)
        active(dbeExportFile)
        active(dbeRun)
}
 
void unsetFileName(DBE dbe, int i) {
        set(dbeExportFile, "C:\\Temp\\")
        inactive(dbeExportFile)
        inactive(dbeRun)
}
 
/******************************************************************************
        MAIN
******************************************************************************/
if (!contextOk) {
        halt
}
 
dbBaselineSetAll = create("Baseline Set Information") // Export selected BaselineSet with Modules")
 
dbeCurrentFolderField = field(dbBaselineSetAll, "Current Project/Folder:", fullName(currFolder), 52, true)
 
dbeLabelFrame = frame(dbBaselineSetAll, "", 250, 77)
 
dbeDescriptionLabel = label(dbBaselineSetAll, "Export information about modules in a baseline set to a text file.\n" //-
                        "  > first select a baseline set definition from the list below\n" //-
                        "  > next select a baseline set created from the previously selected BLS definition\n" //-
                        "  > use 'Browse' to specify where to store the output text file.")
        dbeDescriptionLabel -> "top" -> "inside" -> dbeLabelFrame
        dbeDescriptionLabel -> "left" -> "inside" -> dbeLabelFrame
        dbeDescriptionLabel -> "bottom" -> "inside" -> dbeLabelFrame
 
dbeListsFrame = frame(dbBaselineSetAll, "", 250, 255)
        dbeListsFrame -> "top" -> "flush" -> dbeLabelFrame
 
dbeBLSDLabel = label(dbBaselineSetAll, "Baseline Set Definitions in current Project/Folder:")
        dbeBLSDLabel -> "top" -> "inside" -> dbeListsFrame
 
//dbeBLSetDefListView  = list(dbBaselineSetAll, "Baseline Set Definitions in current Project/Folder:",     450, 7, dummyList)
dbeBLSetDefListView  = listView(dbBaselineSetAll, 0, 450, 6, dummyList)
        dbeBLSetDefListView -> "top" -> "flush" -> dbeBLSDLabel
        dbeBLSetDefListView -> "left" -> "inside" -> dbeListsFrame
        dbeBLSetDefListView -> "right" -> "inside" -> dbeListsFrame
        dbeBLSetDefListView -> "bottom" -> "unattached"
 
dbeBLSLabel = label(dbBaselineSetAll, "Baseline Sets created from selected Baseline Set Definition")
        dbeBLSLabel -> "top" -> "flush" -> dbeBLSetDefListView
 
//dbeBLSetListView  = list(dbBaselineSetAll, "Baseline Sets created from selected Baseline Set Definition:",     450, 10, dummyList)
dbeBLSetListView  = listView(dbBaselineSetAll, 0, 450, 6, dummyList)
        dbeBLSetListView -> "top" -> "flush" -> dbeBLSLabel
        dbeBLSetListView -> "left" -> "inside" -> dbeListsFrame
        dbeBLSetListView -> "right" -> "inside" -> dbeListsFrame
        dbeBLSetListView -> "bottom" -> "inside" -> dbeListsFrame
 
dbeFileLabel = label(dbBaselineSetAll, "Output to file:")
        dbeFileLabel -> "top" -> "flush" -> dbeListsFrame
dbeExportFile = fileName(dbBaselineSetAll, "C:\\Temp\\", "*.txt", "txt files")
 
left(dbBaselineSetAll)
dbeRun     = apply(dbBaselineSetAll, "Run", doRunScript)
 
realize dbBaselineSetAll
 
fillBaselineSetDefList()
 
insertColumn(dbeBLSetDefListView, 0, "Name", 200, iconNone)
insertColumn(dbeBLSetDefListView, 1, "Description", 150, iconNone)
 
inactive(dbeExportFile)
inactive(dbeRun)
 
insertColumn(dbeBLSetListView, 0, "BLS Version", 90, iconNone)
insertColumn(dbeBLSetListView, 1, "Created On", 170, iconNone)
insertColumn(dbeBLSetListView, 2, "Created By", 115, iconNone)
insertColumn(dbeBLSetListView, 3, "Status", 43, iconNone)
 
set(dbeBLSetDefListView, doSelect, undoSelect, doSelect)
 
set(dbeBLSetListView, setFileName, unsetFileName, setFileName)
 
show(dbBaselineSetAll)

now I'm curious

thanks in advance

Karl

Re: Problem with listViews
SystemAdmin - Thu Oct 14 06:01:43 EDT 2010

kabr - Thu Oct 14 05:44:49 EDT 2010

alright, here's the complete code:

// BaselineSets.dxl
 
 
pragma runLim, 0
 
string dummyList[]      = {}
 
Folder currFolder = current Folder 
 
DB  dbBaselineSetAll       = null
DBE dbeCurrentFolderField  = null
DBE dbeLabelFrame          = null
DBE dbeDescriptionLabel    = null
DBE dbeListsFrame          = null
DBE dbeBLSDLabel           = null
DBE dbeBLSetDefListView    = null
DBE dbeBLSLabel            = null
DBE dbeBLSetListView       = null
DBE dbeFileLabel           = null
DBE dbeExportFile          = null
DBE dbeRun                 = null
 
BaselineSetDefinition bsdglobal = null
 
string strbsd     = ""
string strVersion = ""
 
bool statusBLS = false
 
/******************************************************************************
    contextOK
******************************************************************************/
bool contextOk() {
        currFolder = current Folder
        
        if (null currFolder) {
                infoBox("Please run this script from within a folder")
                return false
        }
        return true
}
 
bool fileExists_(string strfilename) {
    Stat s 
    s = create strfilename 
    if (null s) return false 
    delete s 
    return true 
}
 
/******************************************************************************
        fillBaselineSetDefinitions
******************************************************************************/
 
void fillBaselineSetDefList() {
        empty(dbeBLSetDefListView)
        j       = 0
        string bsdName = ""
        string bsdDesc = ""
        BaselineSetDefinition bsd
 
        for bsd in current Folder do {
                bsdName = name(bsd) 
                bsdDesc = description(bsd)
 
                insert(dbeBLSetDefListView, j, "", iconNone)
                set(dbeBLSetDefListView, j, 0, bsdName)
                set(dbeBLSetDefListView, j, 1, bsdDesc)
                j++
        }
        if (null bsdName) {
                insert(dbeBLSetDefListView, 0, "", iconNone)
                set(dbeBLSetDefListView, 0, 0, "(No Baseline Set Definitions)")
                set(dbeBLSetDefListView, 0, 1, "in current folder")
        }
}
 
void doRunScript(DB btn) {
        string bsdName = ""
        string strTemp = ""
        string strCompare = ""
        string strDate = ""
        string strbs = ""
        BaselineSet bs
        ModuleVersion mv
        Baseline bl
        Baseline blcompare
        string strDatebl = ""
        string strfilename = ""
        Module currmod
        ModName_ currmodname
 
        strfilename = get(dbeExportFile)
        Stream out = write strfilename 
        out << "List of Modules contained in specific Baseline Set" "\n\n"
 
        for strTemp in dbeBLSetListView do {
                strbs = strTemp
        }
        
        if (null bsdglobal) {
                ack "Please select a baseline set before you continue!"
                halt
        }
        
        for bs in bsdglobal do {
                strMajor = major(bs) ""
                strMinor = minor(bs) ""
                strVersion = versionID(bs) ""
                strDateof = stringOf(dateOf(bs))
                bsdName = strVersion ", created " strDateof
                if (strVersion == strbs) {
                        break
                }
        }
 
        out << "Baseline Set Definition Information:\n"
        out << "Name       : " name(bsdglobal) "\n"
        out << "Description: " description(bsdglobal) "\n\n"
 
        out << "Baseline Set Information:\n"
        out << "Version    : " strVersion "\n"
        if (isOpen(bs) == true) {
                out << "Status     : Open\n"
        } else {
                out << "Status     : Closed\n"
        }
        out << "Annotation : " annotation(bs) "\n"
        out << "created by : " user(bs) "\n"
        out << "created on : " dateOf(bs) "\n"
        out << "\n"
        out << "Modules:\n"
 
        for mv in all bs do {
                bl = baseline mv
                if (null bl) {
                        strCompare = ""
                        strDate = ""
                } else {
                        currmod = read((fullName mv),false,true)
                        if (!null currmod) {
                                strCompare = (major bl) "." (minor bl) " " (suffix bl) ""
                                for blcompare in currmod do {
                                        tmpString = (major blcompare) "." (minor blcompare) " " (suffix blcompare) ""
                                        if (tmpString == strCompare) {
                                                strDate = ", created on " (dateOf blcompare) ""
                                        }
                                }
                                close(currmod)
                        }
                }
                out << (fullName mv) " "
                string vString = (versionString mv)
                if (vString != "") {
                        out << "[" (versionString mv) "]" 
                } else {
                        out << "[-]"
                }
                out << strDate "\n"
        }
        close(out)
        string buttons[] = {"OK"} 
        int answer = messageBox("BLSD report done",buttons, msgInfo)
}
 
/******************************************************************************
        doSelect
******************************************************************************/
void doSelect(DBE bsdList, int j) {
        string strTemp = get(dbeBLSetDefListView)
        if (strTemp == "(No Baseline Set Definitions)") {
                halt
        }
        int i = 0
        string strbsd = ""
        strTemp = ""
        string strMajor = ""
        string strMinor = ""
        string strVersion = ""
        string strDateof = ""
        string bsdName = ""
        string bsdDesc = ""
        string blsUser = ""
        BaselineSet bs
 
        for strTemp in bsdList do {
                if (strTemp == "No Baseline Set Definitions") halt
                strbsd = strTemp
        }
        empty(dbeBLSetListView)
        for bsdglobal in current Folder do {
                bsdName = name(bsdglobal)
                bsdDesc = description(bsdglobal)
                if (bsdName == strbsd) {
                        break
                }
        }
        for bs in bsdglobal do {
                strMajor = major(bs) ""
                strMinor = minor(bs) ""
                strVersion = versionID(bs) ""
                strDateof = stringOf(dateOf(bs))
                blsUser = user(bs)
                bsdName = strVersion ", created " strDateof
 
                if (!isOpen(bs)) {
                        insert(dbeBLSetListView, i, "",iconNone)
                        set(dbeBLSetListView, i, 3, "closed")
                } else {
                        insert(dbeBLSetListView, i, "",iconNone)
                        set(dbeBLSetListView, i, 3, "open")
                }
                set(dbeBLSetListView, i, 0, strVersion)
                set(dbeBLSetListView, i, 1, strDateof)
                set(dbeBLSetListView, i, 2, blsUser)
                i++
        }
}
 
void undoSelect(DBE dbe, int i) {
        empty(dbeBLSetListView)
        inactive(dbeExportFile)
        inactive(dbeRun)
        set(dbeExportFile, "C:\\Temp\\")
}
 
void setFileName(DBE dbe, int i) {
        strbsd = get(dbeBLSetListView, i)
        bsdName = get(dbeBLSetDefListView)
        string exportFileName = "C:\\Temp\\BLS_" bsdName "_" strbsd ".txt"
        set(dbeExportFile, exportFileName)
        active(dbeExportFile)
        active(dbeRun)
}
 
void unsetFileName(DBE dbe, int i) {
        set(dbeExportFile, "C:\\Temp\\")
        inactive(dbeExportFile)
        inactive(dbeRun)
}
 
/******************************************************************************
        MAIN
******************************************************************************/
if (!contextOk) {
        halt
}
 
dbBaselineSetAll = create("Baseline Set Information") // Export selected BaselineSet with Modules")
 
dbeCurrentFolderField = field(dbBaselineSetAll, "Current Project/Folder:", fullName(currFolder), 52, true)
 
dbeLabelFrame = frame(dbBaselineSetAll, "", 250, 77)
 
dbeDescriptionLabel = label(dbBaselineSetAll, "Export information about modules in a baseline set to a text file.\n" //-
                        "  > first select a baseline set definition from the list below\n" //-
                        "  > next select a baseline set created from the previously selected BLS definition\n" //-
                        "  > use 'Browse' to specify where to store the output text file.")
        dbeDescriptionLabel -> "top" -> "inside" -> dbeLabelFrame
        dbeDescriptionLabel -> "left" -> "inside" -> dbeLabelFrame
        dbeDescriptionLabel -> "bottom" -> "inside" -> dbeLabelFrame
 
dbeListsFrame = frame(dbBaselineSetAll, "", 250, 255)
        dbeListsFrame -> "top" -> "flush" -> dbeLabelFrame
 
dbeBLSDLabel = label(dbBaselineSetAll, "Baseline Set Definitions in current Project/Folder:")
        dbeBLSDLabel -> "top" -> "inside" -> dbeListsFrame
 
//dbeBLSetDefListView  = list(dbBaselineSetAll, "Baseline Set Definitions in current Project/Folder:",     450, 7, dummyList)
dbeBLSetDefListView  = listView(dbBaselineSetAll, 0, 450, 6, dummyList)
        dbeBLSetDefListView -> "top" -> "flush" -> dbeBLSDLabel
        dbeBLSetDefListView -> "left" -> "inside" -> dbeListsFrame
        dbeBLSetDefListView -> "right" -> "inside" -> dbeListsFrame
        dbeBLSetDefListView -> "bottom" -> "unattached"
 
dbeBLSLabel = label(dbBaselineSetAll, "Baseline Sets created from selected Baseline Set Definition")
        dbeBLSLabel -> "top" -> "flush" -> dbeBLSetDefListView
 
//dbeBLSetListView  = list(dbBaselineSetAll, "Baseline Sets created from selected Baseline Set Definition:",     450, 10, dummyList)
dbeBLSetListView  = listView(dbBaselineSetAll, 0, 450, 6, dummyList)
        dbeBLSetListView -> "top" -> "flush" -> dbeBLSLabel
        dbeBLSetListView -> "left" -> "inside" -> dbeListsFrame
        dbeBLSetListView -> "right" -> "inside" -> dbeListsFrame
        dbeBLSetListView -> "bottom" -> "inside" -> dbeListsFrame
 
dbeFileLabel = label(dbBaselineSetAll, "Output to file:")
        dbeFileLabel -> "top" -> "flush" -> dbeListsFrame
dbeExportFile = fileName(dbBaselineSetAll, "C:\\Temp\\", "*.txt", "txt files")
 
left(dbBaselineSetAll)
dbeRun     = apply(dbBaselineSetAll, "Run", doRunScript)
 
realize dbBaselineSetAll
 
fillBaselineSetDefList()
 
insertColumn(dbeBLSetDefListView, 0, "Name", 200, iconNone)
insertColumn(dbeBLSetDefListView, 1, "Description", 150, iconNone)
 
inactive(dbeExportFile)
inactive(dbeRun)
 
insertColumn(dbeBLSetListView, 0, "BLS Version", 90, iconNone)
insertColumn(dbeBLSetListView, 1, "Created On", 170, iconNone)
insertColumn(dbeBLSetListView, 2, "Created By", 115, iconNone)
insertColumn(dbeBLSetListView, 3, "Status", 43, iconNone)
 
set(dbeBLSetDefListView, doSelect, undoSelect, doSelect)
 
set(dbeBLSetListView, setFileName, unsetFileName, setFileName)
 
show(dbBaselineSetAll)

now I'm curious

thanks in advance

Karl

Your code tries to fill the columns before inserting them in list view. The order in the code should be:

insertColumn(dbeBLSetDefListView, 0, "Name", 200, iconNone)
insertColumn(dbeBLSetDefListView, 1, "Description", 150, iconNone)
 
fillBaselineSetDefList()

Re: Problem with listViews
kabr - Thu Oct 14 06:36:21 EDT 2010

SystemAdmin - Thu Oct 14 06:01:43 EDT 2010

Your code tries to fill the columns before inserting them in list view. The order in the code should be:

insertColumn(dbeBLSetDefListView, 0, "Name", 200, iconNone)
insertColumn(dbeBLSetDefListView, 1, "Description", 150, iconNone)
 
fillBaselineSetDefList()

Ooh, that simple!
sometimes you just don't see the wood for the trees

thanks a lot Pekka

Karl